Yeah, that’s an unavoidable side effect of low dynamic range. The brightness of an individual color channel can never go beyond 1.0, and as it starts clipping out of range and the other colors keep rising, the whole thing tends toward white, which washes out the image.
The only option to brighten the image without washing it out is to reduce the thickness of the black lines using the ‘Scanline Thickness’ parameter.
if you’d like to be a guinea pig, I’ve been working on modulating the thickness by the luminance of the underlying pixel (enable the ‘hybrid scanlines’ mode in the parameters):
// Super-basic scanline shader
// (looks bad at non-integer scales)
// by hunterk
// license: public domain
// Parameter lines go here:
#pragma parameter THICKNESS "Scanline Thickness" 2.0 1.0 12.0 1.0
#pragma parameter DARKNESS "Scanline Darkness" 0.50 0.0 1.0 0.05
#pragma parameter BRIGHTBOOST "Scanline Boost Bright" 0.1 0.0 0.2 0.1
#pragma parameter HYBRID "Hybrid Scanlines" 0.0 0.0 1.0 1.0
#if defined(VERTEX)
#if __VERSION__ >= 130
#define COMPAT_VARYING out
#define COMPAT_ATTRIBUTE in
#define COMPAT_TEXTURE texture
#else
#define COMPAT_VARYING varying
#define COMPAT_ATTRIBUTE attribute
#define COMPAT_TEXTURE texture2D
#endif
#ifdef GL_ES
#define COMPAT_PRECISION mediump
#else
#define COMPAT_PRECISION
#endif
COMPAT_ATTRIBUTE vec4 VertexCoord;
COMPAT_ATTRIBUTE vec4 COLOR;
COMPAT_ATTRIBUTE vec4 TexCoord;
COMPAT_VARYING vec4 COL0;
COMPAT_VARYING vec4 TEX0;
vec4 _oPosition1;
uniform mat4 MVPMatrix;
uniform COMPAT_PRECISION int FrameDirection;
uniform COMPAT_PRECISION int FrameCount;
uniform COMPAT_PRECISION vec2 OutputSize;
uniform COMPAT_PRECISION vec2 TextureSize;
uniform COMPAT_PRECISION vec2 InputSize;
// compatibility #defines
#define vTexCoord TEX0.xy
#define SourceSize vec4(TextureSize, 1.0 / TextureSize) //either TextureSize or InputSize
#define OutSize vec4(OutputSize, 1.0 / OutputSize)
void main()
{
gl_Position = MVPMatrix * VertexCoord;
TEX0.xy = TexCoord.xy * 1.0004;
}
#elif defined(FRAGMENT)
#if __VERSION__ >= 130
#define COMPAT_VARYING in
#define COMPAT_TEXTURE texture
out vec4 FragColor;
#else
#define COMPAT_VARYING varying
#define FragColor gl_FragColor
#define COMPAT_TEXTURE texture2D
#endif
#ifdef GL_ES
#ifdef GL_FRAGMENT_PRECISION_HIGH
precision highp float;
#else
precision mediump float;
#endif
#define COMPAT_PRECISION mediump
#else
#define COMPAT_PRECISION
#endif
uniform COMPAT_PRECISION int FrameDirection;
uniform COMPAT_PRECISION int FrameCount;
uniform COMPAT_PRECISION vec2 OutputSize;
uniform COMPAT_PRECISION vec2 TextureSize;
uniform COMPAT_PRECISION vec2 InputSize;
uniform sampler2D Texture;
COMPAT_VARYING vec4 TEX0;
// compatibility #defines
#define Source Texture
#define vTexCoord TEX0.xy
#define SourceSize vec4(TextureSize, 1.0 / TextureSize) //either TextureSize or InputSize
#define OutSize vec4(OutputSize, 1.0 / OutputSize)
#ifdef PARAMETER_UNIFORM
// All parameter floats need to have COMPAT_PRECISION in front of them
uniform COMPAT_PRECISION float THICKNESS;
uniform COMPAT_PRECISION float DARKNESS;
uniform COMPAT_PRECISION float BRIGHTBOOST;
uniform COMPAT_PRECISION float HYBRID;
#else
#define THICKNESS 1.0
#define DARKNESS 0.5
#define BRIGHTBOOST 1.1
#define HYBRID 0.0
#endif
vec3 RGBtoYIQ(vec3 RGB){
const mat3 yiqmat = mat3(
0.2989, 0.5870, 0.1140,
0.5959, -0.2744, -0.3216,
0.2115, -0.5229, 0.3114);
return RGB * yiqmat;
}
float modulate(float var, float luma, float toggle){
float temp = var;
temp -= round(luma * 0.55 * var) * toggle;
return clamp(temp, 0.0, 10.0);
}
void main()
{
float lines = fract(vTexCoord.y * SourceSize.y);
float scale_factor = floor((OutputSize.y / InputSize.y) + 0.4999);
vec4 screen = COMPAT_TEXTURE(Source, vTexCoord);
float luma = RGBtoYIQ(screen.rgb).r;
float thick = modulate(THICKNESS, luma, HYBRID);
float dark = modulate(DARKNESS, luma, HYBRID);
FragColor = (lines > (1.0 / scale_factor * thick)) ? screen : screen * vec4(1.0 - dark);
}
#endif
That should make the image significantly brighter by letting more of the brighter lines shine through.
